欢迎来到查IC网

【记录】存储管理器

来源:互联网   2022-07-19 阅读:17

1. 概要

存储管理器负责管理2440的所有内存设备。2440的地址线ADDR0~ADDR26,即最大执行寻址2^27=128M空间。


CPU通过8根片选信号nGCS0~nGCS7,控制bank0~bank7,每个bank大小为128M,这样就实现了须知1G地址空间。

这里写图片描述
除此之外,0x4800~0x5FFFFFFF,地址空间为特殊寄存器地址范围,控制不同的硬件单元模块。

这里写图片描述

存储器与外设

不同的bank可以接不同的外设设备,2440对多允许接入8个外设。CPU寻址时,向内存管理器发送地址,内存管理器负责访问不同的外设。
开发板上的外设连接。

这里写图片描述

使用SDRAM

访问SDRAM芯片,需要的配置信息
1. 地址线
2. 数据线,8/16/32位,需要设置数据宽度
3. 时钟频率
4. 芯片相关

应用程序与上节的LED程序完全相同,不同的是上节程序在SRAM上运行,此次程序在SDRAM上运行。


启动流程

  1. 复位后,NAND控制器将NAND FLASH中前4k内容复制到片内SRAM中(steppingstone,地址0x0000,0000)

  2. 初始化,关看门狗,初始化存储控制器

  3. 将Steppingstone中的代码全部复制到SDRAM中

  4. 跳转到SDRAM中,继续执行

这里写图片描述

汇编程序

@*************************************************************************

@ File:head.S

@ 功能:设置SDRAM,将程序复制到SDRAM,然后跳到SDRAM继续执行

@*************************************************************************       


.equ        MEM_CTL_base,       0x48000000

.equ        SDRAM_base,         0x30000000


.text

.global _start

_start:

    bl  disable_watch_dog               @ 关闭WATCHDOG,否则CPU会不断重启

    bl  memsetup                        @ 设置存储控制器

    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中

    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行

on_sdram:

    ldr sp, =0x34000000                 @ 设置堆栈

    bl  main

halt_loop:

    b   halt_loop


disable_watch_dog:

    @ 往WATCHDOG寄存器写0即可

    mov r1,     #0x53000000

    mov r2,     #0x0

    str r2,     [r1]

    mov pc,     lr      @ 返回


copy_steppingstone_to_sdram:

    @ 将Steppingstone的4K数据全部复制到SDRAM中去

    @ Steppingstone起始地址为0x00000000,SDRAM中起始地址为0x30000000


    mov r1, #0

    ldr r2, =SDRAM_base

    mov r3, #4*1024

1:  

    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据,并让源地址加4

    str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中,并让目地地址加4

    cmp r1, r3          @ 判断是否完成:源地址等于Steppingstone的未地址?

    bne 1b              @ 若没有复制完,继续

    mov pc,     lr      @ 返回


memsetup:

    @ 设置存储控制器以便使用SDRAM等外设


    mov r1,     #MEM_CTL_base       @ 存储控制器的13个寄存器的开始地址

    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址

    add r3,     r1, #52             @ 13*4 = 54

1:  

    ldr r4,     [r2], #4            @ 读取设置值,并让r2加4

    str r4,     [r1], #4            @ 将此值写入寄存器,并让r1加4

    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器

    bne 1b                          @ 若没有写成,继续

    mov pc,     lr                  @ 返回



.align 4

mem_cfg_val:

    @ 存储控制器13个寄存器的设置值

    .long   0x22011110      @ BWSCON

    .long   0x00000700      @ BANKCON0

    .long   0x00000700      @ BANKCON1

    .long   0x00000700      @ BANKCON2

    .long   0x00000700      @ BANKCON3  

    .long   0x00000700      @ BANKCON4

    .long   0x00000700      @ BANKCON5

    .long   0x00018005      @ BANKCON6

    .long   0x00018005      @ BANKCON7

    .long   0x008C07A3      @ REFRESH

    .long   0x000000B1      @ BANKSIZE

    .long   0x00000030      @ MRSRB6

    .long   0x00000030      @ MRSRB7


效果

LED的闪烁效果比在SRAM上执行时,速度慢,原因是SDRAM的访问速度比SRAM慢。
既然如此,为什么还要使用SDRAM呢?主要原因是SRAM虽然性能很好,但价格还是很高的,所以2240片内只内置了4k的SRAM,当我们的程序超过4k时,就无法单独在片内的SRAM内执行了。此时SRAM只负责一部分的初始化工作以及将NAND FLASH中的代码复制到SDRAM中,程序的执行则完全在SDRAM中进行。


免责声明:
本站部份内容系网友自发上传与转载,不代表本网赞同其观点;
如涉及内容、版权等问题,请在30日内联系,我们将在第一时间删除内容!

相关技术

    查IC网